认识 Aero / 数组与元组

数组与元组

数组:同一类型的一串值

let arr = [1, 2, 3];
print(arr[0]);   // 1

print(arr[2]);   // 3

数组用方括号 [1, 2, 3],元素用 arr[0] 访问,下标从 0 开始。

数组的类型是 [元素类型; 长度]。上面 arr 的类型是 [i64; 3]。长度是类型的一部分——[i64; 3] 和 [i64; 4] 是两个不同的类型,不能互相赋值。

数组元素必须同类型

// let bad = [1, true];   // 错误:数组元素类型不一致

修改元素

let arr = [1, 2, 3];
arr[0] = 100;
print(arr[0]);   // 100

数组字面量直接索引

print([10, 20, 30][1]);   // 20

空数组

[] 推不出元素类型,必须注解:

let empty: [i64; 0] = [];

数组长度写在类型里,没有运行时求长度的内建函数——len() 只接受 str。需要长度时直接用你知道的常量,或者用 Vec(长度可运行时变化)。

数组的坑:越界不检查

Aero 的原生数组([T; N])访问不做越界检查(编译期只检查字面量长度的常量情况,运行时越界是未定义行为)。别写:

let arr = [1, 2, 3];
// print(arr[5]);   // 运行时越界,结果不可预测,别这么干

自己保证下标在 0 <= i < 长度 范围内。这是系统级语言的常见风格——快,但把责任交给你。

动态数组(Vec)的越界行为不同:Vec 的 get(i) 和 set(i, v) 带有边界检查,越界时 get 返回 0,set 被忽略,不会崩溃。Vec 的完整方法表见内建函数速查。

元组:不同类型打包

let t = (10, true);
print(t[0]);   // 10

print(t[1]);   // true

元组用圆括号 (a, b),元素可以不同类型。类型写作 (i64, bool)。

元组索引必须是整数常量,而且编译期检查范围:

let t = (10, true);
print(t[0]);   // 10

// print(t[2]);   // 编译错误:元组索引越界

// print(t[i]);   // 编译错误:元组索引必须是整数常量

两个写不出来的语法,记住别试:

  • 没有 t.0 写法——t.0 会报解析错误,只能用 t[0]。
  • 没有解构——let (a, b) = t; 不支持,只能逐个取值。
  • 元组适合"临时打包几个相关值",比如函数返回多个结果:

    fn divmod(a: i64, b: i64) -> (i64, i64) {
        return (a / b, a % b);
    }
    
    let r = divmod(17, 5);
    print(r[0]);   // 3
    
    print(r[1]);   // 2
    

    数组 vs 元组,怎么选

  • 元素同类型、数量可变逻辑(循环遍历)→ 数组。
  • 少量不同类的值打包 → 元组。
  • 注意 Aero 的原生数组不支持在运行时改变长度(没有 push/pop),也没法用变量做数组长度([i64; n] 的 n 必须是编译期常量)。需要动态长度就用 Vec。

    Aero 1.2.5 新增:元组模式匹配

    以下为 Aero 1.2.5 新增内容。

    元组可以直接放进 match,每个位置写一个子 pattern:

    let point = (3, 4);
    match (point) {
        (0, 0) => { print("origin\n"); }
        (x, 0) => { print("on x-axis\n"); }
        (0, y) => { print("on y-axis\n"); }
        (x, y) => { print("(%d, %d)\n", x, y); }
    }
    // 打印 (3, 4)
    

    (x, 0) 里 0 是字面量匹配,x 是绑定。

    带 guard

    let t = (3, 4);
    match (t) {
        (a, b) if a > b => { print("first > second\n"); }
        (a, b) if a < b => { print("first < second\n"); }
        _ => { print("equal\n"); }
    }
    // 打印 first < second
    

    练习

    1. 写一个函数 sum3(arr: [i64; 3]) -> i64 返回三个元素之和,用 [5, 6, 7] 验证。

    2. 写一个函数返回 (商, 余数),用负数测试一次,观察结果(想想 -17 / 5 是 -3 还是 -4)。

    3. 用循环累加 [1, 2, 3, 4, 5] 的元素,打印总和(提示:循环里用变量下标访问 arr[i])。

    4. 用元组模式匹配改写练习 2 的返回值处理:写一个 match (divmod(17, 5)),把商和余数分别打印。

    Aero 文档 · 基于 Aero 1.2.6 文档整理 · MIT
    SereinTeam